[零基础入门学习]·43·转移指令的原理·操作符offset ·jmp指令· 依据位移进行转移的jmp指令

第9章 转移指令的原理

可以修改IP，或同时修改CS和IP的指令统称为转移指令。概括地讲，转移指令就是可以控制CPU执行内存中某处代码的指令。

8086CPU的转移行为有以下几类。

• 只修改IP时，称为段内转移，比如：jmp ax。
• 同时修改CS和IP时，称为段间转移，比如：jmp 1000:0。

由于转移指令对IP的修改范围不同，段内转移又分为：短转移和近转移。

• 短转移IP的修改范围-128~127。
• 近转移IP的修改范围-32768~32767。

8086CPU的转移指令分为以下几类。

• 无条件转移指令（如：jmp）
• 条件转移指令
• 循环指令（如：loop）
• 过程
• 中断

这些转移指令转移的前提条件不同，但转移的基本原理是相同的。我们在这一章主要通过深入学习无条件转移jmp来理解CPU执行转移指令的基本原理。

9.1 操作符 offset

操作符 offset 在汇编语言中是由编译器处理的符号，它的功能是取得标号的偏移地址。比如下面的程序：

asssume cs:codesg
codesg segment
    start:mov ax,offset start   ;相当于mov ax,0
    s:  mov ax,offset s     ;相当于mov ax,3
codesg ends
end start

在上面的程序中，offset操作符取得了标号start和s的偏移地址0和3，所以指令：
mov ax,offset start相当于 mov ax,0，因为start是代码段中的标号，它所标记的指令是代码段中的第一条指令，偏移地址为0；
mov ax,offset s 相当于 mov ax,3，因为s是代码段中的标号，它所标记的指令是代码段中的第二条指令，第一条指令长度位3个字节，则s的偏移地址为3。

问题 9.1

有如下程序段，添写两条指令，使该程序在运行中将s处的一条指令复制到s0处。

assume cs:codesg
codesg segment
    s:  mov ax,bx       ;mov ax,bx的机器码占两个字节
        mov si,offset s
        mov di,offset s0
        ____________
        ____________
    s0: nop         ;nop的机器码占用一个字节
        nop
codesg ends
end s

思考后看分析。

分析：

1. s和s0处的指令所在的内存单元的地址是多少？cs:offset s和cs:offset s0。
2. 将s处的指令复制到s0处，就是将cs:offset s处的数据复制到cs:offset s0处。
3. 段地址已知在cs中，偏移地址offset s和 offset s0 已经送入si和di中。
   4.要复制的数据有多长？mov ax,bx指令的长度位两个字节，即1个字。

程序如下。

assume cs:codesg
codesg segment
    s:  mov ax,bx       ;mov ax,bx的机器码占两个字节
        mov si,offset s
        mov di,offset s0
        mov ax,cs:[si]
        mov cs:[di],ax
    s0: nop         ;nop的机器码占用一个字节
        nop
codesg ends
end s

9.2 jmp指令

jmp为无条件转移指令，可以只修改IP，也可以同时修改CS和IP。

jmp指令要给出两种信息：

1. 转移的目的地址
2. 转移的距离（段间转移、段内短转移、段内近转移）

不同的给出目的地址的方法，和不同的转移位置，对应有不同格式的jmp指令。下面的几节内容中，我们以给出目的地址的不同方法为主线，讲解jmp指令的主要应用格式和CPU执行转移指令的基本原因。

9.3 依据位移进行转移的jmp指令

jmp short 标号（转到标号处执行指令）

这个格式的jmp指令实现的是段内短转移,它对IP的修改范围为-128~127，也就是说，它向前转移时可以最多越过128个字节，向后转移可以最多越过127个字节。jmp指令中的“short”符号，说明指令进行的是短转移。jmp指令中的“标号”是代码段中的标号，指明了指令要转移的目的地，转移指令结束后，CS:IP应该指向标号处的指令。

比如：

程序 9.1

assume cs:codesg

codesg segment
    start:mov ax,0
        jmp short s
        add ax,1
    s:  inc ax
codesg ends
end start

上面的程序执行后，ax中的值为1，因为执行jmp short s后，越过了 add ax,1，IP指向了标号s处的inc ax。也就是说，程序只进行了一次ax加1的操作。
汇编指令jmp short s 对应的机器指令应该是什么样的呢？我们先看一下别的汇编指令和其相应的机器指令。

汇编指令	机器码
mov ax, 0123h	B8 23 01
mov ax, ds:[0123h]	A1 23 01
push ds:[0123h]	FF 36 23 01

可以看到，在一般的汇编指令中，汇编指令中的idata（立即数），不论它是表示一个数据还是内存单元的偏移地址，都会在对应的机器指令中出现，因为CPU执行的是机器指令，它必须要处理这些数据或地址。

我们在Debug中将程序9.1翻译称为机器码，看到的结果如图9.1所示。

对照汇编源程序，我们可以看到，Debug将jmp short s中的s表示为inc ax指令的偏移地址8，并将jmp short s 表示为jmp 0008，表示转移到cs:0008处。这一切似乎合理，可是当我们查看jmp short s 或是 jmp 0008所对应的机器码，却发现了一些问题。

jmp 0008（Debug中的表示）或jmp short s（汇编语言中的表示）所对应的机器码为EB 03，注意，这个机器码中竟不包含转移的目的地址，这意味着，CPU在执行EB 03 的时候，并不知道转移的目的地址。那么，CPU根据什么进行转移呢？它转移到哪里呢？

令人奇怪的是，汇编指令jmp short s中，明明是带有转移的目的地址（由标号s表示）的，可翻译成机器指令后，怎么目的地址就没了呢？没有了目的地址，CPU如何知道转移到哪里呢？

我们把程序9.1改写一下，变成下面的这样：

程序 9.2

assume cs:codesg

codesg segment
    start:mov ax,0
        mov bx,0
        jmp short s
        add ax,1
    s:  inc ax
codesg ends
end start

我们在Debug中将程序9.2翻译成为机器码，看到的结果如图9.2所示。

比较一下程序9.1和9.2用Debug查看的结果，注意，两个程序中的jmp指令都要使IP指向inc ax指令，但是程序9.1的inc ax指令的偏移地址为8，而程序9.2的inc指令的偏移地址为000BH。我们再来看两个程序中的jmp指令所对应的机器码，都是 EB 03。这说明CPU在执行jmp指令的时候并不需要转移的目的地址。两个程序中的jmp指令的转移目的地址并不一样，一个吃cs:0008，另一个是cs:000B，如果机器指令中包含了转移的目的地址的话，那么它们的机器码应该是不同的。可是它们对应的机器码都是EB 03，这说明在机器指令中并不包含转移目的地址。如果机器指令中不包含目的地址话，那么也就是说，CPU不需要这个目的地址就可以实现对IP的修改。
CPU不是神仙，它只能处理你提供给它的东西，jmp指令的机器码中不包含转移目的地的地址，那么，CPU如何知道将IP改为多少呢？所以，在jmp指令的机器码中，一定包含了某种信息，使得CPU可以将它当作修改IP的依据。这种信息是什么呢？我们一步步地分析。

我们先简单回忆一下CPU执行指令的过程（如果你需要更多的回忆，可以复习一下2.10节的内容）。

1. 从CS:IP指向内存单元读取指令，读取的指令进入指令缓冲器；
2. (IP)=(IP)+所读取指令的长度，从而指向下一条指令；
3. 执行指令。转到1，重复这个过程。

按照这个步骤，我们参考图9.2看一下，程序9.2中jmp short s指令的读取和执行过程：

1. (CS)=0BBDH，(IP)=0006H,CS:IP指向EB 03（jmp short s的机器码）
2. 读取指令码EB 03 进入指令缓冲器；
3. (IP)=(IP)+所读取指令的长度 = (IP)+2=0008H,CS:IP指向add ax,1；
4. CPU执行指令缓冲器中的指令 EB 03；
5. 指令EB 03执行后，(IP)=000BH,CS:IP指向inc ax。

从上面的过程中我们看到，CPU将指令EB 03读入后，IP指向了下一条指令，即CS:0008处的add ax,1，接着执行EB 03。如果EB 03没有对IP进行修改的话，那么接下来CPU将执行add ax,1，可是，CPU执行的EB 03却是一条修改IP的转移指令，执行后(IP)=000BH,CS:IP指向inc ax，CS:0008处的add ax,1没有被执行。

CPU在执行 EB 03 的时候是根据什么修改的IP，使其指向目标指令呢？就是根据指令码中的03。注意，要转移的目的地址是CS：000B，而CPU执行EB 03时，当前的(IP)=0008H,如果将当前的IP值加3，使(IP)=000BH,CS:IP就可指向目标指令。在转移指令EB 03中并没有告诉CPU要转移的目的地址，却告诉了CPU要转移的位移，即将当前的IP向后移动了3个字节。因为程序1、2中的jmp指令的位移相同，都是向后3个字节，所以它们的机器码都是EB 03。

原来如此，在“jmp short 标号”指令所对应的机器码中，并不包含转移的目的地址，而包含的是转移的位移。这个位移，是编译器根据汇编指令中的“标号”计算出来的，具体的计算方法如图9.3所示。

实际上，“jmp short 标号”的功能为：(IP)=(IP)+8位位移。

1. 8位位移=标号处的地址-jmp指令后的第一个字节的地址；
2. short指明此处的位移为8位位移；
3. 8位位移的范围为-128~127，用补码表示（如果你对补码还不了解，请阅读附录2）；
4. 8位位移由编译程序在编译时算出。

还有一种和“jmp short 标号”功能相近的指令格式，jmp near ptr 标号，它实现的是段内近转移。

“jmp near ptr 标号”的功能为：(IP)=(IP)+16位位移。

1. 16位位移=标号处的地址-jmp指令后的第一个字节的地址；
2. near ptr 指明此处的位移为16位位移，进行的是段内近转移；
3. 16位位移的范围为-32768~32767，用补码表示；
4. 16位位移由编译程序在编译时算出。