[零基础入门学习]·34·更灵活定位内存地址·[bx+idata]·用[bx+idata]的方式进行数组的处理

7.5 [bx+idata]

在前面，我们用[bx]的方式来指明一个内存单元，还可以用一种更为灵活的方式来指明内存：[bx+idata]表示一个内存单元，它的偏移地址为(bx)+idata(bx中的数值加上idata)。

我们看一下指令mov ax,[bx+200]的含义：
将一个内存单元的内容送入ax，这个内存单元的长度位2字节（字单元），存放一个字，偏移地址为bx中的数值加上200，段地址在ds中。
数学化的描述为：(ax)=((ds)*16+(bx)+200)
改指令也可以写成如下格式(常用):
mov ax,[200+bx]
mov ax,200[bx]
mov ax,[bx].200

问题7.1

用Debug查看内容，结果如下：
2000:1000 BE 00 06 00 00 00 ......
写出下面的程序执行后，ax、bx、cx中的内容。

mov ax,2000H
mov ds,ax
mov bx,1000H
mov ax,[bx]
mov cx,[bx+1]
add cx,[bx+2]

思考后看分析。

分析：
mov ax,[bx]
访问的字单元的段地址在ds中，(ds)=2000H;偏移地址在bx中，(bx)=1000H；指令执行后(ax)=00BEH。
mov cx,[bx+1]
访问的字单元的段地址在ds中，(ds)=2000H;偏移地址=(bx)+1=1001H;指令执行后(cx)=0600H。
add cx,[bx+2]
访问的字单元的段地址在ds中，(ds)=2000H;偏移地址=(bx)+2=1002H;指令执行后(cx)=0606H。

用[bx+idata]的方式进行数组的处理

有了[bx+idata]这种表示内存单元的方式，我们就可以用更高级的结构来看待索要处理的数据。我们通过下面的问题来理解这一点。
在codesg中填写代码，将datasg中定义的第一个字符串转化为大写，第二个字符串转化为小写。

assume cs:codesg,ds:datasg

datasg segment
    db 'BaSiC'
    db 'MinIX'
datasg ends

codesg segment
start:
codesg segment

end start

按照我们原来的方法，用[bx]的方式定位字符串中的字符。代码段中的程序如下。

    mov ax,datasg
    mov ds,ax
    mov bx,0

    mov cx,5
s:  mov al,[bx]
    and al,11011111b
    mov [bx],al
    inc bx
    loop s

    mov bx,5
    mov cx,5
s0: mov al,[bx]
    or al,00100000b
    mov [bx],al
    inc bx
    loop s0

现在，我们有了[bx+idata]的方式，就可以用更简化的方法来完成上面的程序。观察datasg段中的两个字符串，一个的起始地址为0，另一个的起始地址为5。我们可以将这两个字符串看作两个数组，一个从0开始存放，另一个从5开始存放。那么我们可以用[0+bx]和[5+bx]的方式在同一个循环中定位这两个字符串中的字符。在这里，0和5给定了两个字符串的起始偏移地址，bx中给出了从起始偏移地址开始的相对地址。这两个字符串在内存中的起始地址是不一样的，但是它们中的每一个字符，从起始地址开始的相对地址变化是相同的。改进的程序如下。

    mov ax,datasg
    mov ds,ax
    mov bx,0

    mov cx,5
s:  mov al,[bx]     ;定位第一个自付出中的字符
    and al,11011111b
    mov [bx],al

    mov al,[5+bx]       ;定位第二个自付出中的字符
    or al,00100000b
    mov [5+bx],al

    inc bx
    loop s

程序也可以写成下面的样子：

    mov ax,datasg
    mov ds,ax
    mov bx,0

    mov cx,5
s:  mov al,0[bx]        ;定位第一个自付出中的字符
    and al,11011111b
    mov 0[bx],al

    mov al,5[bx]        ;定位第二个自付出中的字符
    or al,00100000b
    mov 5[bx],al

    inc bx
    loop s

如果用高级语言，比如C语言来描述上面的程序，大致是这样的：

char a[5]="BaSiC"
char b[5]="MinIX"
main()
{
    int i;
    i=0;
    do
    {
        a[i]=a[i]&0xDF; 
        b[i]=b[i]|0x20; 
        i++;
    }
    while(i<5)
}

如果你熟悉C语言的话，可以比较一下这个C程序和上面的汇编程序的相似之处。尤其注意它们定位字符串的方式。
C语言：a[i]，b[i]
汇编语言：0[bx],5[bx]
通过比较，我们可以发现，[bx+idata]的方式为高级语言实现数组提供了便利机制。